File:Cr6spiral3d.png

 

This plot was created with Gnuplot by n.

/*  
this is batch file for Maxima  5.13.0
http://maxima.sourceforge.net/
tested in wxMaxima 0.7.1
using draw package ( interface to gnuplot ) to draw on the screen


draws  critical orbit = orbit of critical point
 

Adam Majewski fraktal.republika.pl
with help of 
Mario Rodriguez Riotorto http://www.telefonica.net/web2/biomates
*/


/*  */

c:%i*0.21687214+0.37496784;


/* define function ( map) for dynamical system z(n+1)=f(zn,c)  */
f(z,c):=expand (z*z + c); /* expand speed up  computations and fix the stack overflow problem. Robert Dodier */

/* maximal number of iterations */
iMax:100000; /* to big couses bind stack overflow */
EscapeRadius:10;

/* define z-plane ( dynamical ) */
zxMin:-0.8;
zxMax:0.2;
zyMin:-0.2;
zyMax:0.8;

/* resolution is proportional to number of details and time of drawing */
iXmax:1000;
iYmax:1000;


/* compute critical point */
zcr:rhs(solve(diff(f(z,c),z,1)));
/* save critical point to 2 lists */
xcr:makelist (realpart(zcr), i, 1, 1); /* list of re(z) */
ycr:makelist (imagpart(zcr), i, 1, 1); /* list of im(z) */	

/* compute attracting fixed point */
fixed:solve([z=f(z,c)], [z]);
zfa:if cabs(2*rhs(fixed[1]))<1 then rhs(fixed[1]) else rhs(fixed[2]);
/* check multipliers of fixed points */
float(cabs(2*rhs(fixed[1])));
float(cabs(2*rhs(fixed[2])));
/* save attracting fixed point to 2 lists */
xfa:makelist (realpart(zfa), i, 1, 1); /* list of re(z) */
yfa:makelist (imagpart(zfa), i, 1, 1); /* list of im(z) */	


/* ------------------- compute forward orbit of critical point in 6 subsets ----------*/
z:zcr; /* first point  */
for i:1 thru 6 step 1 do
block
(
  z:f(z,c),
  if i=1 then orbit1:[z]
	elseif i=2 then orbit2:[z]
	elseif i=3 then orbit3:[z]
	elseif i=4 then orbit4:[z]
	elseif i=5 then orbit5:[z]
	elseif i=6 then orbit6:[z]
  );

for i:6 thru iMax step 1 do
block
(
  z:f(z,c),
  
  if abs(z)>EscapeRadius 
	then exit(i) 
	else (
		j:mod(i,6),
		if j=0 then orbit1:endcons(z,orbit1)
		elseif j=1 then orbit2:endcons(z,orbit2)
		elseif j=2 then orbit3:endcons(z,orbit3)
		elseif j=3 then orbit4:endcons(z,orbit4)
		elseif j=4 then orbit5:endcons(z,orbit5)
		elseif j=5 then orbit6:endcons(z,orbit6)
		
		)
  );

z1:makelist(i*6,i,1,length(orbit1));
z2:makelist((i+1)*6,i,1,length(orbit2));
z3:makelist((i+2)*6,i,1,length(orbit3))$
z4:makelist((i+3)*6,i,1,length(orbit4))$
z5:makelist((i+4)*6,i,1,length(orbit5))$
z6:makelist((i+5)*6,i,1,length(orbit6))$


/* draw reversed orbit of beta  using draw package */
load(draw);
draw3d(
    title= concat(" dynamical plane for f(z,c):=z*z+",string(c)),
	user_preamble = "set size square;set key out;set key top right",
	file_name = "cr_6spiral_3d",
    terminal  = 'png,
	pic_width  = iXmax,
    pic_height = iYmax,
	/* yrange = [zyMin,zyMax],
    xrange = [zxMin,zxMax],
	*/
	xlabel     = "Z.re ",
    ylabel     = "Z.im",
    point_type    = filled_circle,
	points_joined = false,
	
	point_size    = 0.8,
	key = "critical point",
	color		  =magenta,
	points(xcr,ycr,[0]),
	
	point_size    = 0.2,
	
	color		  =red,
	key = "1-spiral of critical orbit",
	points(map (realpart,orbit1),map (imagpart,orbit1),z1),
	
	color		  =orange,
	key = "2-spiral of critical orbit",
	points(map (realpart,orbit2),map (imagpart,orbit2),z2),
	
	color		  =yellow,
	key = "3-spiral of critical orbit",
	points(map (realpart,orbit3),map (imagpart,orbit3),z3),
	
	color		  =green,
	key = "4-spiral of critical orbit",
	points(map (realpart,orbit4),map (imagpart,orbit4),z4),
	
	color		  =cyan,
	key = "5-spiral of critical orbit",
	points(map (realpart,orbit5),map (imagpart,orbit5),z5),
	
	color		  =blue,
	key = "6-spiral of critical orbit",
	points(map (realpart,orbit6),map (imagpart,orbit6),z6),
	
	point_size    = 0.8,
	key = "attracting fixed point",
	color		  =black,
	points(xfa,yfa,[iMax+1])
 );

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue