File:DFT approximation to Hilbert filter.png

N = 512;        % DFT size
L = N/2;        % length of plots
odd = 1:2:L;

// Create a segment of the IIR filter and its periodic summation
  h_IIR = zeros(1,L);
  h_periodic = zeros(1,L);
  for n = odd
    h_IIR(n) = 2/(%pi*n);
    h_periodic(n) = 2/(N*tan(%pi*n/N));      % periodic summation
  end

// Equivalent method
// M = 2*L+1;         
// h_IIR = hilb(M);  //513-tap, FIR Hilbert transform filter
// h_IIR = h_IIR(L+2:M);

// Create a 65-tap, FIR Hilbert transform filter
  minimum_display_value = 0.0001;
  M = 65;         
  M2 = (M-1)/2;
// The next 2 statements are equivalent to the one commented out below them
  h_65 = hilb(M);
  h_65 = [h_65(M2+2:M) ones(1,L-M2)*minimum_display_value];   // align with h_IIR
//h_65 = [h_IIR(1:M2)  ones(1,L-M2)*minimum_display_value];   // align with h_IIR

// Create another filter (equivalent to h_periodic) by sampling the DTFT
  H_DFT = %i*[0 -ones(1,L-1) ones(1,L)];
  h_DFT = real(fft(H_DFT, 1));    // inverse FFT
  h_DFT = h_DFT(2:$);             // align with h_IIR

// Display the results
  r=5; g=3; b=2;  // based on a call to getcolor()
  plot2d(odd', [h_IIR(odd)' h_DFT(odd)' h_65(odd)'], logflag="nl", style=[g r b],..
        rect=[0,minimum_display_value,256,1], frameflag=1, axesflag=1);

  title("Hilbert filter (green) and two approximations", "fontsize", 4);
  ylabel("impulse response (for n > 0)", "fontsize", 3);
  xlabel("n (odd values only)", "fontsize", 3);

  a = gca();
//a.box = "on";         included in frameflag=1
  a.font_size=3;        //set the tics label font size
  a.x_ticks = tlist(["ticks", "locations", "labels"], [1 51 101 151 201 251],..
  ["1" "51" "101" "151" "201" "251"]);

// Set line thickness of plots
  a.children.children.thickness=3;

// This works too
//f = gcf();
//f.children.children.children.thickness=3;

// Can do it this way when the thicknesses are not all the same:
// pb = a.children.children(1);    // Note that the order (compared to "style") is LIFO
// pr = a.children.children(2);
// pg = a.children.children(3);
// pg.thickness = 3;
// pr.thickness = 3;       // equivalent to set(pr,'thickness',3);
// pb.thickness = 3;