File:RGB color wheel pixel 5.svg

iThe source code of this SVG is valid.

 

This vector image was created with LibreOffice.

; Created in LibreOffice 4 with this LibreLogo program.
; Usage: Put this code into an English language document in LibO Writer,
; and click on the Start icon of the View»Toolbars»Logo toolbar. 
TO subpixel r g b size
FILLCOLOR [r, g, b]
RECTANGLE [size*3, size]
END

TO pixel r g b where width
z = HEADING
v = PENSIZE
IF where = -1 [ ; central RGB pixel for white
	distance = 0
	PENCOLOR “BLACK”
] [
	distance = 150 + 1.5 * width
	PENCOLOR “WHITE”
]
PENUP HEADING where-width
FORWARD distance HEADING 3h
PENSIZE width/5
PENDOWN SQUARE 1.5 * width
PENUP BACK width/2
subpixel r 0 0 width/2 FORWARD width/2
subpixel 0 g 0 width/2 FORWARD width/2
subpixel 0 0 b width/2 BACK width/2
HEADING where-width BACK distance
HEADING z
PENSIZE v
END

TO pie r g b where width
FILLCOLOR [r, g, b]
CIRCLE [300, 300, where, where + width]
pixel r g b where width
FILLCOLOR [r ^ 0xff, g ^ 0xff, b ^ 0xff]
CIRCLE [300, 300, 180 + where, 180 + where + width]
r = r^0xff
g = g^0xff
b = b^0xff
pixel r g b 180+where width
END

PENDOWN HOME CLEARSCREEN HIDETURTLE
i = INPUT “Level or Enter (level = 2)”
IF i = “” [ i = 2 ] [ i = INT i ]
PENCOLOR “INVISIBLE”

size = 360/(12*i)
LEFT size * 1.5

; PICTURE “RGB_color_wheel_%d.svg” % size [ ; from LibO 4.1.1
PICTURE [
FILLCOLOR “BLACK” CIRCLE 300 + size * 6
FILLCOLOR “WHITE” CIRCLE 300

REPEAT 2*i+1 [
	u = (REPCOUNT-1) * 255/(2*i)
	pie 255 255 - INT u 0 REPCOUNT * size size
]
REPEAT 2*i [
	u = REPCOUNT * 255/(2*i)
	pie 255 0 INT u 60 + (REPCOUNT + 1) * size size 
]
REPEAT 2*i-1 [
	u = REPCOUNT * 255/(2*i)
	pie 255 - INT u 0 255 120 + (REPCOUNT + 1) * size size 
]
FILLCOLOR “WHITE” CIRCLE 100
pixel 255 255 255 -1 size
]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse