File:Simple CV Joint animated with OpenSCAD.gif

//Simple CV Joint animated with OpenSCAD
//created by https://commons.wikimedia.org/wiki/User:MichaelFrey
//based on https://commons.wikimedia.org/wiki/File:Simple_CV_Joint_animated.gif
//by https://commons.wikimedia.org/wiki/User:Pwld

r1=25; //inner ball
r3=5;  //small balls

n=3; //grooves

r2=r1+r3;

r4=5; //Diameter for the rotary axes

h=80; //lenght of the axed

ang=-30; //angle betwhen the two axes

c =6; //cut off on the gear

convexity=20;
outershellOverhang = 5; //the finger needs to be longer
outershellClearance=3;

outershellThicknes=1;

$fn=120;

//--------------------

//rot = $t*360;
rot = $t*360/3;

color([1,0,0])
rotate([0,0,0])
rotate([rot,0,0]){
     outshell();
 }
 
 
 color([1,1,0])
 rotate([0,ang/2,0])
 rotate([rot,0,0]){
     balls();
 }
 
  color([0,1,0])
 rotate([0,ang,0])
 rotate([rot,0,0]){
    gear();
 }
module outshell(){
    for (i = [0 : 1 : n]){
        difference(){
            rotate([360/n*i])
            rotate_extrude(convexity = convexity)
            translate([r1,0,0])
            circle(r = r3+outershellThicknes);

            rotate([360/n*i])
            rotate_extrude(convexity = convexity)
                translate([r1,0,0])
                circle(r = r3);
            translate([r2+r3+2+outershellOverhang,0,0])
            cube(size =  (r2+2)*2 ,     center = true);
            
            sphere(r = r1+outershellClearance);
        }
    }
    
    translate([-r2-h/2, 0,0])
    rotate([90,90,90])
    cylinder(h=h, r=r4, center=true);
//}
}

 
 //balls
module balls(){
    for (i = [0 : 1 : n*2]){
        rotate([360/n*i/2])
        translate([0, r1,0])
        sphere(r = r3);
    }
 }
 
 module gear(){ //"gear" ball
    intersection(){
    difference(){
        rotate([0,90,0])
        sphere(r =r1);
        
         for (i = [0 : 1 : n]){
             rotate([360/n*i])
            rotate_extrude(convexity = convexity)
            translate([r1,0,0])
            circle(r = r3);
         }

     }
    cube(size =  [(r1-c)*2,(r1+2)*2,(r1+2)*2] ,     center = true);
    }
    translate([h/2, 0,0])
    rotate([90,90,90])
    cylinder(h=h, r=r4, center=true);
}

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue