File:Graph paper mm A4.pdf

; Created in LibreOffice 4 with this LibreLogo program.
 ; Usage: Put this code into an English language document in LibO Writer,
 ; and click on the Start icon of the View»Toolbars»Logo toolbar.
 ; Modify these values, if needed:
 
 color = “GRAY”
 margin = 0.7cm ; min. margin width
 line1 = 1cm ; main grid
 line2 = 0.5cm ; medium grid, set to line1 to remove these lines
 line3 = 1mm ; small grid, set to line1 to remove these lines
 line1width = 1pt ; 1in/72
 line2width = 1pt/2 ; 1in/144
 line3width = 1in/300; for 300dpi
 
 TO lines width dist
     GLOBAL margin, line1
     l = [INT ((PAGESIZE[0] – margin * 2) / line1), INT ((PAGESIZE[1] – margin * 2) / line1)]
     leftmargin =  (PAGESIZE[0]-l[0]*line1) / 2
     topmargin =  (PAGESIZE[1]-l[1]*line1) / 2
     REPEAT 1 + PAGESIZE[width]/dist  [
         IF (REPCOUNT – 1) * dist > (l[width] * line1) [ BREAK ]
         PENUP POSITION [leftmargin + (REPCOUNT-1) * dist * (1-width), (PAGESIZE[1] – topmargin) * (1-width) + ((REPCOUNT - 1) * dist + topmargin)  * width]
         PENDOWN HEADING 90*width
         PENDOWN FORWARD l[1-width] * line1
     ] 
 END
 
 HOME CLEARSCREEN HIDETURTLE
 PICTURE [
     PENCOLOR “INVISIBLE” FILLCOLOR “WHITE”
     RECTANGLE PAGESIZE PENCOLOR color
     PENSIZE line1width lines 0 line1 lines 1 line1
     PENSIZE line2width lines 0 line2 lines 1 line2
     PENSIZE line3width lines 0 line3 lines 1 line3
 ]