File:Polgar starchess board.pdf

; Created in LibreOffice 4 with this LibreLogo program.
 ; Usage: Put this code into an English language document in LibO Writer,
 ; and click on the Start icon of the View»Toolbars»Logo toolbar.
 ; requested chess font: http://mip.noekeon.org/HTMLTTChess/chess_merida_unicode.html
 ; for other setup, positions, modify the arguments of the chess call in the end of the file
 GLOBAL FIX_SVG_EXPORT
 FIX_SVG_EXPORT = 0pt ; 3pt FOR SVG export, OR SET zero FOR other usage
 
 TO number s n head
         HEADING head
         LEFT 155 FORWARD 5*s/7
         HEADING head
         LABEL n
 END
 
 TO hexagon s n
         p = POSITION
         H = HEADING
         PENUP LEFT 30 FORWARD s LEFT 120 PENDOWN
         PENCOLOR “BLACK” FILLCOLOR “WHITE”
         REPEAT 5 [ FORWARD s LEFT 60 ] FILL PENUP
         FONTCOLOR “GRAY” FONTSIZE 12 FONTFAMILY “Nimbus Sans L”
         POSITION p number s n 0
         POSITION p number s n 180
         POSITION p HEADING H
 END
 
 TO zigzag size
 REPEAT 2 [ 
 	FORWARD size
 	RIGHT 60
 	FORWARD size
 	LEFT 60
 ]
 END
 
 TO chess WHITE BLACK
 PENCOLOR “BLACK” ; PENDOWN RIGHT 60
 FILLCOLOR “INVISIBLE” PENSIZE 2
 FILLCOLOR “BLUE” PENSIZE 10 PENDOWN
 HEADING 0 RIGHT 30
 size = 43
 REPEAT 6 [ zigzag size FORWARD size LEFT 60 zigzag size RIGHT 120 ] CLOSE
 LEFT 60 PENUP FORWARD size
 
 PENUP 
 PENSIZE 2
 data = {“K”: “♔♚”, “Q”: “♕♛”, “R”: “♖♜”, “B”: “♗♝”, “N”: “♘♞”, “P”: “♙♟”, “o”: “•••”, “x”: “✕✕✕”, “*”: “⭑⭑⭑”}
 HEADING 0
 n = 0
 figures = WHITE + “ ” + BLACK + “ ”
 M = SQRT size**2 – (size/2)**2
 n = 0
 FOR i IN [0, 1, 4, 6, 5, 5, 6, 4, 1] [
 	PENUP RIGHT 90 FORWARD size * 1.5 LEFT 90 BACK i * 2 * M + M
 	REPEAT [1, 2, 7, 6, 5, 6, 7, 2, 1][REPCOUNT-1] [
 		n = n + 1
 		hexagon size n
                 p = “[QKBRNP]%d ” % n
                 what = SEARCH (p, figures)
                 IF what [
                         what = what.start()
                         FONTFAMILY “Chess Merida Unicode”
                         FONTSIZE 45
                         H = HEADING
                         HEADING 0 FORWARD FIX_SVG_EXPORT
                         k = data[figures[what]]
                         FONTCOLOR “WHITE”
                         LABEL k[2]
                         FONTCOLOR “BLACK”
                         LABEL k[what > COUNT WHITE]
                         BACK FIX_SVG_EXPORT HEADING H
                 ]
 
 		FORWARD M*2
 	]
 ]
 END
 
 HOME CLEARSCREEN
 PENUP POSITION [70, PAGESIZE[1]/2]
 PENJOINT “MITER” HIDETURTLE
 
 PICTURE [
 ; chess “K1 Q2 P3” “K4 R5 B6 N7” ; example notation
 chess “” “” 
 ]

== References ==

<div class="reflist " style=" list-style-type: decimal;">
'"`UNIQ--references-00000001-QINU`"'</div>